Настройки пользователей и прав: Группы пользователей. Пользователи - Добавить пользователей: Администратор, Менеджер1, Менеджер2. В Группы доступа создать группу с профилем Менеджер по продажам и добавить туда Менеджер1 и Менеджер2. Для Менеджер1 и Менеджер2 на закладке «Права доступа» добавить включить в группу «Менеджер».

НСИ и маркетинг – Несколько видов цен. Продажи – Заказы клиентов (Заказ со склада и под заказ) и Индивидуальные соглашения. Создать вид цен «Закупочная» (СКД цены поступления), «Нижний порог рентабельности» (наценка 3% на «Закупочную») и «Оптовую» (наценка 10% на «Закупочную»). Добавить организацию, склад, вид номенклатуры и номенклатуру. Создать клиента (соглашение с «Оптовыми» ценами продажи), поставщика и тестовое поступление (установить цены номенклатуры).

Задачи: 1) Хранение вида цен «Нижний порог рентабельности» (в РС).

2) Добавить новый реквизит на форму и обеспечить его заполнение в расширении.

3) Контроль цены расположить в процедуре ОбработкаПроверкиЗаполнения модуля объекта.

Добавляем расширение «НижнийПорогРентабельности» (префикс «экз»). Добавить в расширение Справочники: Пользователи и ВидыЦен.

Создать в расширении РС экз\_ЦенаНижнегоПорогаРентабельности. Добавить измерения: Пользователь и ВидЦены (контролировать заполнение). Выбрать в РС для Менеджер1 цену «Нижний порог рентабельности».


Запустить 1С с параметром запуска /С ЗапуститьОбновлениеИнформационнойБазы.

Добавить документ «Заказ клиента», Форму документа и ТЧ на форме «Товары», параметры сеанса ТекущийПользователь, РС «Цены номенклатуры» и «Курсы валют» (со всеми изм. и ресурс.) в расширение.


Добавить колонку ТЧ «экз\_НижнийПорогРентабельности» число 15.2


ТЧ «Товары» на форме добавить в расширение и вывести новый реквизит на форму.

Добавить в расширение Процедуру После экз\_ОбработкаПроверкиЗаполнения



Модуль объекта расширения перед этой процедурой добавить функцию:





Функция ПолучитьНижнийПорогРентабельности(ТаблицаТовары, ПроверкаСебестоимости = Ложь) Экспорт

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| Товары.Номенклатура КАК Номенклатура,

| Товары.Характеристика КАК Характеристика,

| Товары.НомерСтроки КАК НомерСтроки,

| Товары.Упаковка КАК Упаковка,

| Товары.Цена КАК Цена

|ПОМЕСТИТЬ ТаблицаТовары

|ИЗ

| &ТаблицаТовары КАК Товары

|;

|

|////////////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| ТаблицаТовары.Номенклатура КАК Номенклатура,

| ТаблицаТовары.Характеристика КАК Характеристика,

| ТаблицаТовары.НомерСтроки КАК НомерСтроки,

| ТаблицаТовары.Цена КАК Цена,

| ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки1, 1) \* ЕСТЬNULL(ЦеныНоменклатурыСрезПоследних.Цена, 0) / ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки2, 1) \* ВЫБОР

| КОГДА &Валюта <> ЦеныНоменклатурыСрезПоследних.Валюта

| ТОГДА ВЫБОР

| КОГДА ЕСТЬNULL(КурсыВалютыЦены.Кратность, 0) > 0

| И ЕСТЬNULL(КурсыВалютыЦены.Курс, 0) > 0

| И ЕСТЬNULL(КурсыВалюты.Кратность, 0) > 0

| И ЕСТЬNULL(КурсыВалюты.Курс, 0) > 0

| ТОГДА КурсыВалютыЦены.Курс \* КурсыВалюты.Кратность / (КурсыВалюты.Курс \* КурсыВалютыЦены.Кратность)

| ИНАЧЕ 0

| КОНЕЦ

| ИНАЧЕ 1

| КОНЕЦ КАК экз\_НижнийПорогРентабельности

|ИЗ

| ТаблицаТовары КАК ТаблицаТовары

| ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(

| КОНЕЦПЕРИОДА(&Дата, ДЕНЬ),

| ВидЦены В

| (ВЫБРАТЬ

| экз\_ЦенаНижнегоПорогаРентабельности.ВидЦены КАК ВидЦены

| ИЗ

| РегистрСведений.экз\_ЦенаНижнегоПорогаРентабельности КАК экз\_ЦенаНижнегоПорогаРентабельности

| ГДЕ

| экз\_ЦенаНижнегоПорогаРентабельности.Пользователь = &Пользователь)

| И (Номенклатура, Характеристика) В

| (ВЫБРАТЬ

| ТаблицаТовары.Номенклатура КАК Номенклатура,

| ТаблицаТовары.Характеристика КАК Характеристика

| ИЗ

| ТаблицаТовары КАК ТаблицаТовары)) КАК ЦеныНоменклатурыСрезПоследних

| ПО ТаблицаТовары.Номенклатура = ЦеныНоменклатурыСрезПоследних.Номенклатура

| И ТаблицаТовары.Характеристика = ЦеныНоменклатурыСрезПоследних.Характеристика

| ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют.СрезПоследних(&Дата, ) КАК КурсыВалютыЦены

| ПО (ЦеныНоменклатурыСрезПоследних.Валюта = КурсыВалютыЦены.Валюта)

| ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют.СрезПоследних(&Дата, Валюта = &Валюта) КАК КурсыВалюты

| ПО (ИСТИНА)";

Если ПроверкаСебестоимости Тогда

Запрос.Текст = Запрос.Текст + "

|ГДЕ

| ТаблицаТовары.Цена < ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки1, 1) \* ЕСТЬNULL(ЦеныНоменклатурыСрезПоследних.Цена, 0) / ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки2, 1) \* ВЫБОР

| КОГДА &Валюта <> ЦеныНоменклатурыСрезПоследних.Валюта

| ТОГДА ВЫБОР

| КОГДА ЕСТЬNULL(КурсыВалютыЦены.Кратность, 0) > 0

| И ЕСТЬNULL(КурсыВалютыЦены.Курс, 0) > 0

| И ЕСТЬNULL(КурсыВалюты.Кратность, 0) > 0

| И ЕСТЬNULL(КурсыВалюты.Курс, 0) > 0

| ТОГДА КурсыВалютыЦены.Курс \* КурсыВалюты.Кратность / (КурсыВалюты.Курс \* КурсыВалютыЦены.Кратность)

| ИНАЧЕ 0

| КОНЕЦ

| ИНАЧЕ 1

| КОНЕЦ";

КонецЕсли;

Запрос.УстановитьПараметр("ТаблицаТовары", ТаблицаТовары);

Запрос.УстановитьПараметр("Дата", Дата);

Запрос.УстановитьПараметр("Валюта", Валюта);

Запрос.УстановитьПараметр("Пользователь", ПараметрыСеанса.ТекущийПользователь);

Запрос.Текст = СтрЗаменить(Запрос.Текст,"&ТекстЗапросаКоэффициентУпаковки1", Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаКоэффициентаУпаковки(

"ТаблицаТовары.Упаковка", "ТаблицаТовары.Номенклатура"));

Запрос.Текст = СтрЗаменить(Запрос.Текст, "&ТекстЗапросаКоэффициентУпаковки2", Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаКоэффициентаУпаковки(

"ЦеныНоменклатурыСрезПоследних.Упаковка", "ЦеныНоменклатурыСрезПоследних.Номенклатура"));

РезультатЗапроса = Запрос.Выполнить();

ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

Возврат ВыборкаДетальныеЗаписи;

КонецФункции

Добавить в функцию:

Функция КонтрольНижнегоПорогаРентабельности()

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| экз\_ЦенаНижнегоПорогаРентабельности.ВидЦены КАК ВидЦены

|ИЗ

| РегистрСведений.экз\_ЦенаНижнегоПорогаРентабельности КАК экз\_ЦенаНижнегоПорогаРентабельности

|ГДЕ

| экз\_ЦенаНижнегоПорогаРентабельности.Пользователь = &Пользователь";

Запрос.УстановитьПараметр("Пользователь", ПараметрыСеанса.ТекущийПользователь);

РезультатЗапроса = Запрос.Выполнить();

Если НЕ РезультатЗапроса.Пустой() Тогда

Возврат Истина;

Иначе

Возврат Ложь;

КонецЕсли;

КонецФункции

Добавить в процедуру:

&После("ОбработкаПроверкиЗаполнения")

Процедура экз\_ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)

Если Отказ Тогда

Возврат;

КонецЕсли;

Если КонтрольНижнегоПорогаРентабельности() Тогда

ВыборкаОшибки = ПолучитьНижнийПорогРентабельности(Товары, Истина);

Если ВыборкаОшибки.Количество() > 0 Тогда

Отказ = Истина;

КонецЕсли;

Пока ВыборкаОшибки.Следующий() Цикл

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "Цена не может быть ниже нижнего порога рентабельности";

Сообщение.Поле = "Объект.Товары["+Формат(ВыборкаОшибки.НомерСтроки-1, "ЧГ=0")+"].Цена";


Сообщение.Сообщить();

КонецЦикла;

КонецЕсли;

КонецПроцедуры

Добавить в расширение Процедуры: После экз\_ТоварыНоменклатураПриИзмененииПосле, экз\_ТоварыХарактеристикаПриИзмененииПосле и экз\_ВалютаПриИзмененииПосле поместить в них вызов ЗаполнитьНижнийПорогРентабельности();



&НаСервере

Функция экз\_НижнийПорогРентабельностиНоменклатуры(ПараметрыЦены)

ТаблицаДанных = Новый ТаблицаЗначений;

ТаблицаДанных.Колонки.Добавить("НомерСтроки", Новый ОписаниеТипов("Число"));

ТаблицаДанных.Колонки.Добавить("Цена", Новый ОписаниеТипов("Число"));

ТаблицаДанных.Колонки.Добавить("Номенклатура", Новый ОписаниеТипов("СправочникСсылка.Номенклатура"));

ТаблицаДанных.Колонки.Добавить("Характеристика", Новый ОписаниеТипов("СправочникСсылка.ХарактеристикиНоменклатуры"));

ТаблицаДанных.Колонки.Добавить("Упаковка", Новый ОписаниеТипов("СправочникСсылка.УпаковкиЕдиницыИзмерения"));

Строка = ТаблицаДанных.Добавить();

ЗаполнитьЗначенияСвойств(Строка, ПараметрыЦены);

ЗаказОбъект = РеквизитФормыВЗначение("Объект");

ВыборкаНижнийПорогРентабельности = ЗаказОбъект.ПолучитьНижнийПорогРентабельности(ТаблицаДанных);

ВыборкаНижнийПорогРентабельности.Следующий();

Возврат ВыборкаНижнийПорогРентабельности.экз\_НижнийПорогРентабельности;

КонецФункции

&НаКлиенте

Процедура ЗаполнитьНижнийПорогРентабельности()

ТекущиеДанные = Элементы.Товары.ТекущиеДанные;

ПараметрыЦены = Новый Структура("Номенклатура, Характеристика, НомерСтроки, Упаковка",

ТекущиеДанные.Номенклатура, ТекущиеДанные.Характеристика, ТекущиеДанные.НомерСтроки, ТекущиеДанные.Упаковка);

ТекущиеДанные.экз\_НижнийПорогРентабельности = экз\_НижнийПорогРентабельностиНоменклатуры(ПараметрыЦены);

КонецПроцедуры

&НаКлиенте

Процедура экз\_ТоварыНоменклатураПриИзмененииПосле(Элемент)

ЗаполнитьНижнийПорогРентабельности();

КонецПроцедуры

&НаКлиенте

Процедура экз\_ТоварыХарактеристикаПриИзмененииПосле(Элемент)

ЗаполнитьНижнийПорогРентабельности();

КонецПроцедуры


&НаКлиенте

Процедура экз\_ВалютаПриИзмененииПосле(Элемент)


ЗаполнитьНижнийПорогРентабельности();

КонецПроцедуры

Добавить проверочный пример под администратором: CRM и маркетинг – Цены (прайслист) – История изменения цен: рассчитать в документе вид цены «Нижний порого рентабельности». Под Менеджер 1 создать документ «Заказ клиента»



Под менеджером 1 не проводится. Сделать такой же документ под менеджером 2.



Под менеджером 2 проводится.