

Администрирование – Общие настройки – Дополнительные реквизиты и сведения: включаем использование. В виды номенклатуры добавляем 3 дополнительных реквизита для серии: «Дата производства» тип Дата, «Срок годности» Число(2), «Процент годности» Число(2).



Для примера добавляем Приобретение товаров и услуг и в приемке создаем Приходный ордер на товары.

Добавляем расширение Экзамен (префикс экз\_). Убираем галку безопасный режим. Очистить в свойствах расширения «Основные роли».



Добавляем в расширение: ТЧ Товары документа «ПриходныйОрдерНаТовары» (реквизиты: Номенклатура, Серия), справочник Номенклатура, СерииНоменклатуры (реквизит ГоденДо) с ТЧ ДополнительныеРеквизиты со всеми реквизитами, ПланыВидовХарактеристик ДополнительныеРеквизитыИСведения реквизит «Значение».

В модуле объекта документа «ПриходныйОрдерНаТовары» процедуру ОбработкаПроверкиЗаполнения добавляем в расширение (после).

&После("ОбработкаПроверкиЗаполнения")

Процедура экз\_ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| ПРЕДСТАВЛЕНИЕССЫЛКИ(ПриходныйОрдерНаТоварыТовары.Номенклатура) КАК НоменклатураПредставление,

| ПриходныйОрдерНаТоварыТовары.НомерСтроки КАК НомерСтроки,

| ПРЕДСТАВЛЕНИЕССЫЛКИ(ПриходныйОрдерНаТоварыТовары.Серия) КАК СерияПредставление,

| ПриходныйОрдерНаТоварыТовары.Серия КАК Серия

|ПОМЕСТИТЬ Исходная

|ИЗ

| Документ.ПриходныйОрдерНаТовары.Товары КАК ПриходныйОрдерНаТоварыТовары

|ГДЕ

| ПриходныйОрдерНаТоварыТовары.Ссылка = &Ссылка

|;

|

|////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| ВЫБОР

| КОГДА СерииНоменклатурыДополнительныеРеквизиты.Значение > 0

| ТОГДА СерииНоменклатурыДополнительныеРеквизиты.Значение

| ИНАЧЕ 0

| КОНЕЦ КАК ЗначениеПГ,

| СерииНоменклатурыДополнительныеРеквизиты.Свойство.Наименование КАК СвойствоНаименование,

| СерииНоменклатурыДополнительныеРеквизиты.Ссылка.Ссылка КАК Ссылка

|ПОМЕСТИТЬ СерииПГ

|ИЗ

| Справочник.СерииНоменклатуры.ДополнительныеРеквизиты КАК СерииНоменклатурыДополнительныеРеквизиты

|ГДЕ

| СерииНоменклатурыДополнительныеРеквизиты.Ссылка В

| (ВЫБРАТЬ

| Исходная.Серия КАК Серия

| ИЗ

| Исходная КАК Исходная)

| И СерииНоменклатурыДополнительныеРеквизиты.Свойство.Заголовок = ""Процент годности""

|;

|

|////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| ВЫБОР

| КОГДА СерииНоменклатурыДополнительныеРеквизиты.Значение > 0

| ТОГДА СерииНоменклатурыДополнительныеРеквизиты.Значение

| ИНАЧЕ 0

| КОНЕЦ КАК ЗначениеКД,

| СерииНоменклатурыДополнительныеРеквизиты.Свойство.Наименование КАК СвойствоНаименование,

| СерииНоменклатурыДополнительныеРеквизиты.Ссылка.Ссылка КАК Ссылка

|ПОМЕСТИТЬ СерииКД

|ИЗ

| Справочник.СерииНоменклатуры.ДополнительныеРеквизиты КАК СерииНоменклатурыДополнительныеРеквизиты

|ГДЕ

| СерииНоменклатурыДополнительныеРеквизиты.Ссылка В

| (ВЫБРАТЬ

| Исходная.Серия КАК Серия

| ИЗ

| Исходная КАК Исходная)

| И СерииНоменклатурыДополнительныеРеквизиты.Свойство.Заголовок = ""Срок годности""

|;

|

|////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| СерииПГ.ЗначениеПГ КАК ЗначениеПГ,

| СерииКД.ЗначениеКД КАК ЗначениеКД,

| СерииКД.Ссылка КАК Ссылка,

| СерииКД.Ссылка.ГоденДо КАК СсылкаГоденДо

|ПОМЕСТИТЬ СерииИтог

|ИЗ

| СерииПГ КАК СерииПГ

| ВНУТРЕННЕЕ СОЕДИНЕНИЕ СерииКД КАК СерииКД

| ПО СерииПГ.Ссылка = СерииКД.Ссылка

|;

|

|////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| Исходная.НомерСтроки КАК НомерСтроки,

| Исходная.НоменклатураПредставление КАК НоменклатураПредставление,

| Исходная.СерияПредставление КАК СерияПредставление,

| СерииИтог.ЗначениеПГ КАК ЗначениеПГ,

| СерииИтог.ЗначениеКД КАК ЗначениеКД,

| СерииИтог.СсылкаГоденДо КАК СсылкаГоденДо,

| РАЗНОСТЬДАТ(&ТекущаяДата, СерииИтог.СсылкаГоденДо, ДЕНЬ) КАК Осталось

|ИЗ

| Исходная КАК Исходная

| ВНУТРЕННЕЕ СОЕДИНЕНИЕ СерииИтог КАК СерииИтог

| ПО Исходная.Серия = СерииИтог.Ссылка";

Запрос.УстановитьПараметр("Ссылка", Ссылка);

Запрос.УстановитьПараметр("ТекущаяДата", Дата);

РезультатЗапроса = Запрос.Выполнить();

ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

Если ВыборкаДетальныеЗаписи.ЗначениеПГ = 0 ИЛИ ВыборкаДетальныеЗаписи.ЗначениеКД = 0 Тогда

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "В выбранной серии неверно заполнены дополнительные реквизиты 'Процент годности' или 'Срок годности'";

Сообщение.Поле = "Товары["+Строка(ВыборкаДетальныеЗаписи.НомерСтроки-1)+"].Серия";

Сообщение.УстановитьДанные(ЭтотОбъект);

Сообщение.Сообщить();

Отказ = Истина;

ИначеЕсли ВыборкаДетальныеЗаписи.ЗначениеКД\*ВыборкаДетальныеЗаписи.ЗначениеПГ/100>ВыборкаДетальныеЗаписи.Осталось Тогда

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "В выбранной серии оставшийся срок годности меньше допустимого порога!";

Сообщение.Поле = "Товары["+Строка(ВыборкаДетальныеЗаписи.НомерСтроки-1)+"].Серия";

Сообщение.УстановитьДанные(ЭтотОбъект);

Сообщение.Сообщить();


Отказ = Истина;

КонецЕсли;


КонецЦикла;


КонецПроцедуры

Добавляем документ «Приобретение товаров и услуг» с текущей датой



Склад и доставка – Приемка: создаем «Приходный ордер на товары» заполняем серии





Во второй строке отклонение от нормы.