
Добавляем новый документ «экзаменПринятьТоварыПоФакту» синоним «Принять товары по факту» и относим к подсистеме Закупки, запрещаем проведение, длинна номера 11. Добавляем реквизиты (копируем из ПриобретениеТоваровУслуг, а Статус из ПриходныйОрдерНаТовары):



У Контрагента настраиваем связи параметров выбора (Отбор.Партнер(Партнер)), у Соглашения связи параметров выбора (Отбор.Партнер(Партнер) не изменять). В модуле объекта документа:

Процедура ОбработкаЗаполнения(ДанныеЗаполнения, ТекстЗаполнения, СтандартнаяОбработка)

Организация = Справочники.Организации.ОрганизацияПоУмолчанию();

Склад = Справочники.Склады.СкладПоУмолчанию();

Статус = Перечисления.СтатусыПриходныхОрдеров.КПоступлению;

Ответственный = Пользователи.ТекущийПользователь();


КонецПроцедуры

Процедура ПриУстановкеНовогоНомера(СтандартнаяОбработка, Префикс)

ПрефиксацияОбъектовСобытия.УстановитьПрефиксИнформационнойБазыИОрганизации(ЭтотОбъект, СтандартнаяОбработка, Префикс);

КонецПроцедуры

Создаем форму объекта документа и форму списка.



Добавить процедуры модуля формы:

&НаСервере

Процедура ПартнерПриИзмененииНаСервере()

ПартнерыИКонтрагенты.ЗаполнитьКонтрагентаПартнераПоУмолчанию(Объект.Партнер, Объект.Контрагент, Истина);

КонецПроцедуры

&НаКлиенте

Процедура ПартнерПриИзменении(Элемент)

ПартнерПриИзмененииНаСервере();

КонецПроцедуры

&НаСервере

Процедура СоглашениеПриИзмененииНаСервере()

РеквизитыСоглашения = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(Объект.Соглашение, "Организация, Склад");

ЗаполнитьЗначенияСвойств(Объект, РеквизитыСоглашения, "Организация, Склад");

КонецПроцедуры

&НаКлиенте

Процедура СоглашениеПриИзменении(Элемент)

СоглашениеПриИзмененииНаСервере();

КонецПроцедуры

&НаКлиенте

Процедура ПослеЗаписи(ПараметрыЗаписи)

Оповестить("Запись\_ПоступлениеТоваровУслуг");

КонецПроцедуры

В обработке УправлениеПоступлением в модуль формы дополняем ЗаполнитьРаспоряженияНаПоступление Строка 1367:

//Экз

| ОБЪЕДИНИТЬ ВСЕ

|

| ВЫБРАТЬ

| экзаменПринятьТоварыПоФакту.Ссылка КАК Ссылка,

| экзаменПринятьТоварыПоФакту.Партнер КАК Партнер,

| экзаменПринятьТоварыПоФакту.Соглашение.ХозяйственнаяОперация,

| ВЫРАЗИТЬ(экзаменПринятьТоварыПоФакту.Номер КАК СТРОКА(11)),

| экзаменПринятьТоварыПоФакту.Дата,

| """",

| ДАТАВРЕМЯ(1, 1, 1),

| &ИмяПриемкаТоваровПоФакту,

| ЛОЖЬ,

| 5,

| ИСТИНА

|ИЗ

| Документ.экзаменПринятьТоварыПоФакту КАК экзаменПринятьТоварыПоФакту


|ГДЕ

| НЕ экзаменПринятьТоварыПоФакту.ПометкаУдаления

| И экзаменПринятьТоварыПоФакту.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыПриходныхОрдеров.КПоступлению)

| И экзаменПринятьТоварыПоФакту.Склад = &Склад

//Экз



Добавляем заполнение параметра строка 1517:


//Экз

Запрос.УстановитьПараметр("ИмяПриемкаТоваровПоФакту", Метаданные.Документы. экзаменПринятьТоварыПоФакту.Синоним);


//Экз

После этого в РМ Приемка будут отображаться документы Принять по факту, у которых статус равен КПоступлению.

Создать документ по Торговый дом "Комплексный" соглашение Регулярные поставки Электро (предпоследнее).



Документ виден в Склад и отгрузка – Приемка (выбрать Склад бытовой техники)



В состав типа данных определяемого типа РаспоряжениеНаПоступление включить созданный документ экзаменПринятьТоварыПоФакту и ПриходныйОрдерНаТовары. Укажем, что документ является основанием для ПриходныйОрдерНаТовары.

Дорабатываем документ ПриходныйОрдерНаТовары. В модуле объекта ПриходныйОрдерНаТовары в процедуре ОбработкаЗаполнения, чтобы при создании ордера на основании нашего документа не было сообщения про отсутствующие товары.

//Экз

Если ТипЗнч(Распоряжение) <> Тип("ДокументСсылка.экзаменПринятьТоварыПоФакту") Тогда

ЗаполнитьТоварыПоТоварамКПоступлению("Номенклатура", ДатаПоступления);

КонецЕсли;

//ЗаполнитьТоварыПоТоварамКПоступлению("Номенклатура", ДатаПоступления);

//Экз

Дополнительно описывать алгоритм заполнения нет смысла, т.к. из РМ Приемка передается структура, которая обрабатывается при заполнении документа.

Убираем движения в регистре ДвижениеТоваров.

//Экз


Если ТипЗнч(Распоряжение) <> Тип("ДокументСсылка.экзаменПринятьТоварыПоФакту") Тогда

ЗаказыСервер.ОтразитьДвижениеТоваров(ДополнительныеСвойства, Движения, Отказ);

КонецЕсли;

//ЗаказыСервер.ОтразитьДвижениеТоваров(ДополнительныеСвойства, Движения, Отказ);

//Экз



При проведении необходимо чтоб по регистру «ТоварыКПоступлению» не было движения «Расход» по ресурсу «КОформлениюОрдеров», при этом «Приход» по ресурсу «КОформлениюПоступленийПоОрдерам» должен остаться. В модуле менеджера в процедуре ИнициализироватьДанныеДокумента меняем вызов ТекстЗапросаТаблицаТоварыКПоступлению на свой:

//Экз

Если ЗначениеЗаполнено(ДокументСсылка.Распоряжение) И ТипЗнч(ДокументСсылка.Распоряжение) = Тип("ДокументСсылка.экзаменПринятьТоварыПоФакту") Тогда

экзамен\_ТекстЗапросаТаблицаТоварыКПоступлениюПоПраспоряжению(Запрос, ТекстыЗапроса, Регистры);

Иначе


ТекстЗапросаТаблицаТоварыКПоступлению(Запрос, ТекстыЗапроса, Регистры);

КонецЕсли;

//ТекстЗапросаТаблицаТоварыКПоступлению(Запрос, ТекстыЗапроса, Регистры);

//Экз

Процедуру экзамен\_ТекстЗапросаТаблицаТоварыКПоступлениюПоПраспоряжению делаем на основании оригинала удаляя движение «расход».



В процедуре модуля менеджера ЗаполнитьПараметрыИнициализации добавляем код:

//Экз

Если ТипЗнч(Реквизиты.Распоряжение) = Тип("ДокументСсылка.экзаменПринятьТоварыПоФакту") Тогда

Запрос.УстановитьПараметр("Распоряжение", ДокументСсылка);


Иначе

Запрос.УстановитьПараметр("Распоряжение", Реквизиты.Распоряжение);

КонецЕсли;

//Запрос.УстановитьПараметр("Распоряжение", Реквизиты.Распоряжение);

//Экз



Создаем Приходный ордер на товары. В Склад и доставка в АРМ «Приемка» по кнопке «Создать ордер» создаем Приходный ордер на товары и заполняем табличную часть товарами (Пылесос "Энергия-SANYO") 12шт. Статус «Принят» и проводим.

Для документа ПриобретениеТоваровУслуг добавляем возможность вводить на основании документа ПриходныйОрдерНаТовары, добавляем реквизит экзаменДокументОснование – тип ДокументСсылка.ПриходныйОрдерНаТовары. Вынести этот реквизит на форму на закладку дополнительно.

В модуле объекта добавляем процедуру

//Экз

Процедура экзаменЗаполнитьДокументНаОснованииПриходногоОрдера(ДокументОснование)

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| ВЫРАЗИТЬ(ПриходныйОрдерНаТовары.Распоряжение КАК Документ.экзаменПринятьТоварыПоФакту).Организация КАК Организация,

| ВЫРАЗИТЬ(ПриходныйОрдерНаТовары.Распоряжение КАК Документ.экзаменПринятьТоварыПоФакту).Партнер КАК Партнер,

| ВЫРАЗИТЬ(ПриходныйОрдерНаТовары.Распоряжение КАК Документ.экзаменПринятьТоварыПоФакту).Контрагент КАК Контрагент,

| ВЫРАЗИТЬ(ПриходныйОрдерНаТовары.Распоряжение КАК Документ.экзаменПринятьТоварыПоФакту).Соглашение КАК Соглашение,

| ПриходныйОрдерНаТовары.Склад КАК Склад,

| ПриходныйОрдерНаТовары.Ссылка КАК экзаменДокументОснование

|ИЗ

| Документ.ПриходныйОрдерНаТовары КАК ПриходныйОрдерНаТовары

|ГДЕ

| ПриходныйОрдерНаТовары.Ссылка = &ДокументОснование

|;

|

|////////////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| ТоварыКОформлениюПоступленияОстатки.Номенклатура КАК Номенклатура,

| ТоварыКОформлениюПоступленияОстатки.Характеристика КАК Характеристика,

| ТоварыКОформлениюПоступленияОстатки.Номенклатура.ЕдиницаИзмерения КАК Упаковка,

| ТоварыКОформлениюПоступленияОстатки.КОформлениюПоступленийПоОрдерамОстаток КАК Количество,

| ТоварыКОформлениюПоступленияОстатки.КОформлениюПоступленийПоОрдерамОстаток КАК КоличествоУпаковок,

| ТоварыКОформлениюПоступленияОстатки.Назначение КАК Назначение,

| ТоварыКОформлениюПоступленияОстатки.Серия КАК Серия,

| ТоварыКОформлениюПоступленияОстатки.Номенклатура.СтавкаНДС КАК СтавкаНДС

|ИЗ

| РегистрНакопления.ТоварыКПоступлению.Остатки(

| ,

| Склад = &Склад

| И ДокументПоступления = &Распоряжение) КАК ТоварыКОформлениюПоступленияОстатки";

Запрос.УстановитьПараметр("ДокументОснование", ДокументОснование.ДокументОснование);

Запрос.УстановитьПараметр("Склад", ДокументОснование.Склад);

Запрос.УстановитьПараметр("Распоряжение", ДокументОснование.ДокументОснование);

РезультатыЗапроса = Запрос.ВыполнитьПакет();

ВыборкаШапка = РезультатыЗапроса[0].Выбрать();

ВыборкаШапка.Следующий();

ЗаполнитьЗначенияСвойств(ЭтотОбъект, ВыборкаШапка);

Товары.Загрузить(РезультатыЗапроса[1].Выгрузить());

КонецПроцедуры

//Экз

В обработке заполнения добавляем ее вызов:

//Экз

ИначеЕсли ДанныеЗаполнения.Свойство("ДокументОснование")

И (ТипЗнч(ДанныеЗаполнения.ДокументОснование) = Тип("ДокументСсылка.ПриходныйОрдерНаТовары")) Тогда

экзаменЗаполнитьДокументНаОснованииПриходногоОрдера(ДанныеЗаполнения);

ЗакупкаПодДеятельность = Справочники.Организации.ЗакупкаПодДеятельность(Организация, Склад, Дата);

//Экз

И в конце процедуры заполнение ЗакупкаПодДеятельность.


//Экз

Если НЕ ЗначениеЗаполнено(ЗакупкаПодДеятельность) Тогда

ЗакупкаПодДеятельность = Справочники.Организации.ЗакупкаПодДеятельность(Организация, Склад, Дата);

КонецЕсли;

//Экз



Добавим контроль поступления товаров по одному распоряжению.

//Экз

Процедура экзаменВыполнитьКонтрольТоваровКОформлениюПоступления(РежимПроведения, Отказ)

Если НЕ ЗначениеЗаполнено(экзаменДокументОснование) Тогда

Возврат;

КонецЕсли;

Запрос = Новый Запрос;

Запрос.УстановитьПараметр("Товары", Товары);

Запрос.УстановитьПараметр("Распоряжение", экзаменДокументОснование.Распоряжение);

Запрос.УстановитьПараметр("МоментВремени", ?(РежимПроведения = РежимПроведенияДокумента.Оперативный, Неопределено, Новый Граница(МоментВремени(), ВидГраницы.Включая)));

Запрос.Текст =

"ВЫБРАТЬ

| Товары.НомерСтроки КАК НомерСтроки,

| Товары.Номенклатура КАК Номенклатура,

| Товары.Характеристика КАК Характеристика,

| Товары.Серия КАК Серия,

| Товары.Склад КАК Склад

|ПОМЕСТИТЬ Товары

|ИЗ

| &Товары КАК Товары

|;

|

|////////////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| МИНИМУМ(Товары.НомерСтроки) КАК НомерСтроки,

| Товары.Номенклатура КАК Номенклатура,

| Товары.Характеристика КАК Характеристика,

| Товары.Серия КАК Серия,

| Товары.Склад КАК Склад,

| &Распоряжение КАК Распоряжение

|ПОМЕСТИТЬ ТоварыДокумента

|ИЗ

| Товары КАК Товары

|

|СГРУППИРОВАТЬ ПО

| Товары.Номенклатура,

| Товары.Характеристика,

| Товары.Серия,

| Товары.Склад

|;

|

|////////////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| ТоварыДокумента.НомерСтроки КАК НомерСтроки,

| ПРЕДСТАВЛЕНИЕ(ТоварыДокумента.Номенклатура) КАК Номенклатура,

| -ТоварыКОформлениюПоступленияОстатки.КОформлениюПоступленийПоОрдерамОстаток КАК Количество

|ИЗ

| ТоварыДокумента КАК ТоварыДокумента

| ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыКПоступлению.Остатки(

| &МоментВремени,

| (Склад, ДокументПоступления, Номенклатура, Характеристика, Серия) В

| (ВЫБРАТЬ

| ТоварыДокумента.Склад,

| ТоварыДокумента.Распоряжение,

| ТоварыДокумента.Номенклатура,

| ТоварыДокумента.Характеристика,

| ТоварыДокумента.Серия

| ИЗ

| ТоварыДокумента КАК ТоварыДокумента)) КАК ТоварыКОформлениюПоступленияОстатки

| ПО ТоварыДокумента.Склад = ТоварыКОформлениюПоступленияОстатки.Склад

| И ТоварыДокумента.Распоряжение = ТоварыКОформлениюПоступленияОстатки.ДокументПоступления

| И ТоварыДокумента.Номенклатура = ТоварыКОформлениюПоступленияОстатки.Номенклатура

| И ТоварыДокумента.Характеристика = ТоварыКОформлениюПоступленияОстатки.Характеристика

| И ТоварыДокумента.Серия = ТоварыКОформлениюПоступленияОстатки.Серия

|ГДЕ

|ТоварыКОформлениюПоступленияОстатки.КОформлениюПоступленийПоОрдерамОстаток < 0";

РезультатЗапроса = Запрос.Выполнить();

Если РезультатЗапроса.Пустой() Тогда

Возврат;

КонецЕсли;

ВыборкаНехваткаТоваров = РезультатЗапроса.Выбрать();

Пока ВыборкаНехваткаТоваров.Следующий() Цикл

ОбщегоНазначенияКлиентСервер.СообщитьПользователю(

"Остаток товара " + ВыборкаНехваткаТоваров.Номенклатура + " по распоряжению превышает оформляемое количество на " + ВыборкаНехваткаТоваров.Количество,

, "Объект.Товары["+Формат(ВыборкаНехваткаТоваров.НомерСтроки-1, "ЧН=0; ЧГ=")+"].Номенклатура",,Отказ);

КонецЦикла;

КонецПроцедуры


//Экз

Добавляем вызов процедуры в обработке проведения.

//Экз

экзаменВыполнитьКонтрольТоваровКОформлениюПоступления(РежимПроведения, Отказ);

//Экз



В модуле менеджера в процедуре ИнициализироватьДанныеДокумента делаем расход по РН ТоварыКПоступлению. На основании «ТекстЗапросаТаблицаТоварыКПоступлению» где из текста запроса оставляем только второй запрос объединения, тот что про «Расход» по ресурсу «КОформлениюПоступленийПоОрдерам» Благодаря чему при проведении документа регистр «ТоварыКПоступлению» будет выводиться в «0».

В процедуре УстановитьПараметрыЗапросаСведенийПоПоступлениям добавляем код:

//Экз

ЭкзРаспоряжение = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Запрос.Параметры.Ссылка, "экзаменДокументОснование");

Если ЗначениеЗаполнено(ЭкзРаспоряжение) Тогда

Запрос.УстановитьПараметр("ДокументПоступления", ЭкзРаспоряжение);


Иначе

Запрос.УстановитьПараметр("ДокументПоступления", Запрос.Параметры.Ссылка);

КонецЕсли;

//Запрос.УстановитьПараметр("ДокументПоступления", Запрос.Параметры.Ссылка);

//Экз



Закупки – Накладные к оформлению – Контроль ордеров: проверим появление документа «Приходный ордер на товары».

Отчет. Текст запроса в СКД

ВЫБРАТЬ

ВЫРАЗИТЬ(ТоварыКПоступлениюОстатки.ДокументПоступления КАК Документ.ПриходныйОрдерНаТовары).Распоряжение КАК Распоряжение,

ТоварыКПоступлениюОстатки.ДокументПоступления КАК ДокументПоступления,

ТоварыКПоступлениюОстатки.Номенклатура КАК Номенклатура,

ТоварыКПоступлениюОстатки.Характеристика КАК Характеристика,

ТоварыКПоступлениюОстатки.Склад КАК Склад,

ТоварыКПоступлениюОстатки.КОформлениюПоступленийПоОрдерамОстаток КАК КОформлениюПоступленийПоОрдерамОстаток

ИЗ

РегистрНакопления.ТоварыКПоступлению.Остатки(, ДокументПоступления ССЫЛКА Документ.ПриходныйОрдерНаТовары) КАК ТоварыКПоступлениюОстатки

ГДЕ

ТоварыКПоступлениюОстатки.КОформлениюПоступленийПоОрдерамОстаток > 0

И ТИПЗНАЧЕНИЯ(ТоварыКПоступлениюОстатки.ДокументПоступления.Распоряжение) = ТИП(Документ.экзаменПринятьТоварыПоФакту)