В модуле менеджера документа ПланПродаж добавляем процедуру

Функция ПолучитьБлокируемыеРеквизитыОбъекта() Экспорт

Результат = Новый Массив;

Результат.Добавить("Статус");

Результат.Добавить("НачалоПериода;УстановитьИнтервал");

Результат.Добавить("ОкончаниеПериода");

Результат.Добавить("Сценарий");

Результат.Добавить("ВидПлана");

Результат.Добавить("Товары;ТоварыПоПериодам");

Возврат Результат;

КонецФункции

В которой в массив добавляются имена реквизитов документа, а через “;” добавляются имена элементов формы.

В ОМ ЗапретРедактированияРеквизитовОбъектовПереопределяемый, в процедуру ПриОпределенииОбъектовСЗаблокированнымиРеквизитами добавляем

// {Экзамен

Объекты.Вставить(Метаданные.Документы.ПланПродаж.ПолноеИмя(), "ПолучитьБлокируемыеРеквизитыОбъекта");

// }Экзамен

В модуль формы объекта документа ПланПродаж в процедуру ПриСозданииНаСервере и ПослеЗаписиНаСервере добавляем

// {Экзамен

//Запрет редактирования

Если Объект.Статус = Перечисления.СтатусыПланов.Утвержден Тогда

ЗапретРедактированияРеквизитовОбъектов.ЗаблокироватьРеквизиты(ЭтаФорма);

КонецЕсли;

// }Экзамен

Также в этот же модуль добавляем

#Область Экзамен

&НаКлиенте

Процедура Подключаемый\_РазрешитьРедактированиеРеквизитовОбъекта(Команда)

Если Не Объект.Ссылка.Пустая() Тогда

ОткрытьФорму("Документ.ПланПродаж.Форма.экзаменРазблокированиеРеквизитов",,,,,,

Новый ОписаниеОповещения("Подключаемый\_РазрешитьРедактированиеРеквизитовОбъектаЗавершение", ЭтотОбъект),

РежимОткрытияОкнаФормы.БлокироватьВесьИнтерфейс);

КонецЕсли;

КонецПроцедуры

&НаКлиенте

Процедура Подключаемый\_РазрешитьРедактированиеРеквизитовОбъектаЗавершение(Результат, ДополнительныеПараметры) Экспорт

Если ТипЗнч(Результат) = Тип("Массив") И Результат.Количество() > 0 Тогда

ЗапретРедактированияРеквизитовОбъектовКлиент.УстановитьДоступностьЭлементовФормы(ЭтаФорма, Результат);

экзаменЗаписьЖурналаРегистрации(Объект.Ссылка);

КонецЕсли;

КонецПроцедуры

&НаСервереБезКонтекста

Процедура экзаменЗаписьЖурналаРегистрации(Ссылка)

ЗаписьЖурналаРегистрации(

"Экзамен.Редактрирование утвержденного плана продаж",

ПредопределенноеЗначение("УровеньЖурналаРегистрации.Информация"),

Метаданные.Документы.ПланПродаж,

Ссылка);

КонецПроцедуры // экзаменЗаписьЖурналаРегистрации()

#КонецОбласти

*Для документа ПланПродаж добавляем произвольную форму (форма в обработке к этой задаче), которая будет открываться для разблокировки реквизитов*