
## Создание своего документа

Создаем документ экзаменПринятьТоварыПоФакту, включаем в подсистему Закупки. Запрещаем проведение.



Настраиваем параметры выбора и связи параметров выбора для реквизитов документа. В модуле объекта документа

Процедура ОбработкаЗаполнения(ДанныеЗаполнения, ТекстЗаполнения, СтандартнаяОбработка)

Организация = Справочники.Организации.ОрганизацияПоУмолчанию();

Склад = Справочники.Склады.СкладПоУмолчанию();

Статус = Перечисления.СтатусыПриходныхОрдеров.КПоступлению;

Ответственный = Пользователи.ТекущийПользователь();


КонецПроцедуры

Процедура ПриУстановкеНовогоНомера(СтандартнаяОбработка, Префикс)

ПрефиксацияОбъектовСобытия.УстановитьПрефиксИнформационнойБазыИОрганизации(ЭтотОбъект, СтандартнаяОбработка, Префикс);

КонецПроцедуры

Создаем форму объекта документа и форму списка.



В модуле формы следующий код

&НаСервере

Процедура ПартнерПриИзмененииНаСервере()

ПартнерыИКонтрагенты.ЗаполнитьКонтрагентаПартнераПоУмолчанию(Объект.Партнер, Объект.Контрагент, Истина);

КонецПроцедуры

&НаКлиенте

Процедура ПартнерПриИзменении(Элемент)

ПартнерПриИзмененииНаСервере();

КонецПроцедуры

&НаСервере

Процедура СоглашениеПриИзмененииНаСервере()

РеквизитыСоглашения = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(Объект.Соглашение, "Организация, Склад");

ЗаполнитьЗначенияСвойств(Объект, РеквизитыСоглашения, "Организация, Склад");

КонецПроцедуры

&НаКлиенте

Процедура СоглашениеПриИзменении(Элемент)

СоглашениеПриИзмененииНаСервере();

КонецПроцедуры

&НаКлиенте

Процедура ПослеЗаписи(ПараметрыЗаписи)

Оповестить("Запись\_ПоступлениеТоваровУслуг");

КонецПроцедуры

## Доработка РМ Приемка

Обработка УправлениеПоступлением. Добавляем свою процедуру в модуль формы

#Область Экзамен

&НаСервереБезКонтекста

Процедура экзаменДополнитьТекстЗапроса(Запрос)

ЗаменяемыйТекст = " И НЕ СоглашенияСПоставщиками.ПометкаУдаления";

ТекстЗамены = " И НЕ СоглашенияСПоставщиками.ПометкаУдаления

|

|ОБЪЕДИНИТЬ ВСЕ

|

|ВЫБРАТЬ

| ПринятьТоварыПоФакту.Партнер,

| ПринятьТоварыПоФакту.Номер,

| ПринятьТоварыПоФакту.Дата,

| ПринятьТоварыПоФакту.Ссылка,

| &ИмяПринятьПоФакту,

| НЕОПРЕДЕЛЕНО,

| НЕОПРЕДЕЛЕНО,

| ЛОЖЬ,

| 5

|ИЗ

| Документ.экзаменПринятьТоварыПоФакту КАК ПринятьТоварыПоФакту

|ГДЕ

| НЕ ПринятьТоварыПоФакту.ПометкаУдаления

| И ПринятьТоварыПоФакту.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыПриходныхОрдеров.КПоступлению)

| И ПринятьТоварыПоФакту.Склад В(&МассивГруппСкладов)";

Если НЕ СтрНайти(Запрос.Текст, ЗаменяемыйТекст) Тогда

ВызватьИсключение "Некорректный текст запроса";

КонецЕсли;


Запрос.Текст = СтрЗаменить(Запрос.Текст, ЗаменяемыйТекст, ТекстЗамены);

Запрос.УстановитьПараметр("ИмяПринятьПоФакту", Метаданные.Документы.экзаменПринятьТоварыПоФакту.Синоним);

КонецПроцедуры // экзаменДополнитьТекстЗапроса()

#КонецОбласти

Вызываем добавленную процедуру из процедуры ЗаполнитьРаспоряженияНаПоступление




После этого в РМ Приемка будут отображаться документы Принять по факту, у которых статус равен КПоступлению.


## Доработка документа Приходный ордер на товары


В состав типа данных определяемого типа РаспоряжениеНаПоступление включим созданный документ ПринятьТоварПоФакту. Укажем, что документ является основанием для ПоступлениеТоваровУслуг.

В модуле объекта ПриходныйОрдерНаТовары в процедуре ОбработкаЗаполнения чтобы при создании ордера на основании нашего документа не было сообщения про отсутствующие товары.

 Дополнительно описывать алгоритм заполнения нет смысла, т.к. из РМ Приемка передается структура, которая обрабатывается при заполнении документа.

После этого из РМ Приемка можно создать Приходный ордер, добавить в него товары и провести. После проведения ордер делает движения по РН ТоварыКПоступлению. Из-за этого в РМ Приемка будут лишние данные. В модуле объекта ордера в обработке проведения добавим следующий код

После этого перепроведем ордер и убедимся, что в РН ТоварыКОформлениюПоступления в качестве документа поступления выступает наш документ.

 У документа Принять товары установим статус – Принято

## Доработка документа Поступление товаров и услуг

Для документа добавим два реквизита экзаменДокументОснование – тип ДокументСсылка.ПриходныйОрдерНаТовары и экзаменРаспоряжение – тип ДокументСсылка.экзаменПринятьТоварыПоФакту. Реквизит экзаменРаспоряжение добавляется т.к. в будущем он будет учувствовать в проведении документа и если его не добавлять, то данные можно получить как экзаменДокументОснование.Распоряжение, что ведет к лишнему обращению к БД.

В модуле объекта добавим процедуру

Процедура экзаменЗаполнитьДокументНаОснованииПриходногоОрдера(ДокументОснование)

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| ВЫРАЗИТЬ(ПриходныйОрдерНаТовары.Распоряжение КАК Документ.экзаменПринятьТоварыПоФакту).Организация КАК Организация,

| ВЫРАЗИТЬ(ПриходныйОрдерНаТовары.Распоряжение КАК Документ.экзаменПринятьТоварыПоФакту).Партнер КАК Партнер,

| ВЫРАЗИТЬ(ПриходныйОрдерНаТовары.Распоряжение КАК Документ.экзаменПринятьТоварыПоФакту).Контрагент КАК Контрагент,

| ВЫРАЗИТЬ(ПриходныйОрдерНаТовары.Распоряжение КАК Документ.экзаменПринятьТоварыПоФакту).Соглашение КАК Соглашение,

| ПриходныйОрдерНаТовары.Склад,

| ПриходныйОрдерНаТовары.Распоряжение КАК экзаменРаспоряжение,

| ПриходныйОрдерНаТовары.Ссылка КАК экзаменДокументОснование

|ИЗ

| Документ.ПриходныйОрдерНаТовары КАК ПриходныйОрдерНаТовары

|ГДЕ

| ПриходныйОрдерНаТовары.Ссылка = &ДокументОснование

|;

|

|////////////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| ТоварыКОформлениюПоступленияОстатки.Номенклатура,

| ТоварыКОформлениюПоступленияОстатки.Характеристика,

| ТоварыКОформлениюПоступленияОстатки.Номенклатура.ЕдиницаИзмерения КАК Упаковка,

| ТоварыКОформлениюПоступленияОстатки.КОформлениюОстаток КАК Количество,

| ТоварыКОформлениюПоступленияОстатки.КОформлениюОстаток КАК КоличествоУпаковок,

| ТоварыКОформлениюПоступленияОстатки.Назначение,

| ТоварыКОформлениюПоступленияОстатки.Серия,

| ТоварыКОформлениюПоступленияОстатки.Номенклатура.СтавкаНДС КАК СтавкаНДС

|ИЗ

| РегистрНакопления.ТоварыКОформлениюПоступления.Остатки(

| ,

| Склад = &Склад

| И ДокументПоступления = &Распоряжение) КАК ТоварыКОформлениюПоступленияОстатки";

РеквизитыОснования = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(ДокументОснование, "Склад, Распоряжение");

Запрос.УстановитьПараметр("ДокументОснование", ДокументОснование);

Запрос.УстановитьПараметр("Склад", РеквизитыОснования.Склад);

Запрос.УстановитьПараметр("Распоряжение", РеквизитыОснования.Распоряжение);

РезультатыЗапроса = Запрос.ВыполнитьПакет();

ВыборкаШапка = РезультатыЗапроса[0].Выбрать();


ВыборкаШапка.Следующий();


ЗаполнитьЗначенияСвойств(ЭтотОбъект, ВыборкаШапка);

Товары.Загрузить(РезультатыЗапроса[1].Выгрузить());


КонецПроцедуры


Добавим вызов этой процедуры в процедуру ОбработкаЗаполнения


Отключим движения по РН ТоварыКПоступлению (так как отключили их и у Приходного ордера)



Теперь необходимо, чтобы при проведении в РН ТоварыКОформлениюПоступления в качестве документа поступления выступал реквизит экзаменРаспоряжение, чтобы регистр закрывался в 0. Для этого в модуле менеджера документа в процедуре ЗаполнитьПараметрыИнициализации вставим следующий код



В процедуре ТекстЗапросаТаблицаТоварыКОформлениюПоступления

Изменили текст запроса для выборки добавленных нами реквизитов. Далее проверяем – если документ основание заполнен, а заполнен он может быть только в 1 случае – при создании на основании Приходного ордера, то в запрос передаем два параметра, которые обрабатываются при формировании таблицы для РН ТоварыКОформлениюПоступления.

Добавим контроль поступления товаров по одному распоряжению.

Процедура экзаменВыполнитьКонтрольТоваровКОформлениюПоступления(РежимПроведения, Отказ)

Если НЕ ЗначениеЗаполнено(экзаменРаспоряжение) Тогда

Возврат;

КонецЕсли;

Запрос = Новый Запрос;

Запрос.УстановитьПараметр("Товары", Товары);

Запрос.УстановитьПараметр("Распоряжение", экзаменРаспоряжение);

Запрос.УстановитьПараметр("МоментВремени", ?(РежимПроведения = РежимПроведенияДокумента.Оперативный, Неопределено, Новый Граница(МоментВремени(), ВидГраницы.Включая)));

Запрос.Текст =

"ВЫБРАТЬ

| Товары.НомерСтроки,

| Товары.Номенклатура,

| Товары.Характеристика,

| Товары.Серия,

| Товары.Склад

|ПОМЕСТИТЬ Товары

|ИЗ

| &Товары КАК Товары

|;

|

|////////////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| МИНИМУМ(Товары.НомерСтроки) КАК НомерСтроки,

| Товары.Номенклатура,

| Товары.Характеристика,

| Товары.Серия,

| Товары.Склад,

| &Распоряжение

|ПОМЕСТИТЬ ТоварыДокумента

|ИЗ

| Товары КАК Товары

|

|СГРУППИРОВАТЬ ПО

| Товары.Номенклатура,

| Товары.Характеристика,

| Товары.Серия,

| Товары.Склад

|;

|

|////////////////////////////////////////////////////////////////////////////////

|ВЫБРАТЬ

| ТоварыДокумента.НомерСтроки,

| ПРЕДСТАВЛЕНИЕ(ТоварыДокумента.Номенклатура) КАК Номенклатура,

| -ТоварыКОформлениюПоступленияОстатки.КОформлениюОстаток КАК Количество

|ИЗ

| ТоварыДокумента КАК ТоварыДокумента

| ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыКОформлениюПоступления.Остатки(

| &МоментВремени,

| (Склад, ДокументПоступления, Номенклатура, Характеристика, Серия) В

| (ВЫБРАТЬ

| ТоварыДокумента.Склад,

| ТоварыДокумента.Распоряжение,

| ТоварыДокумента.Номенклатура,

| ТоварыДокумента.Характеристика,

| ТоварыДокумента.Серия

| ИЗ

| ТоварыДокумента КАК ТоварыДокумента)) КАК ТоварыКОформлениюПоступленияОстатки

| ПО ТоварыДокумента.Склад = ТоварыКОформлениюПоступленияОстатки.Склад

| И ТоварыДокумента.Распоряжение = ТоварыКОформлениюПоступленияОстатки.ДокументПоступления

| И ТоварыДокумента.Номенклатура = ТоварыКОформлениюПоступленияОстатки.Номенклатура

| И ТоварыДокумента.Характеристика = ТоварыКОформлениюПоступленияОстатки.Характеристика

| И ТоварыДокумента.Серия = ТоварыКОформлениюПоступленияОстатки.Серия

|ГДЕ

| ТоварыКОформлениюПоступленияОстатки.КОформлениюОстаток < 0";

РезультатЗапроса = Запрос.Выполнить();

Если РезультатЗапроса.Пустой() Тогда

Возврат;

КонецЕсли;

ВыборкаНехваткаТоваров = РезультатЗапроса.Выбрать();

Пока ВыборкаНехваткаТоваров.Следующий() Цикл

ОбщегоНазначенияКлиентСервер.СообщитьПользователю(

"Остаток товара " + ВыборкаНехваткаТоваров.Номенклатура + " по распоряжению превышает оформляемое количество на " + ВыборкаНехваткаТоваров.Количество,

,

"Объект.Товары["+Формат(ВыборкаНехваткаТоваров.НомерСтроки-1, "ЧН=0; ЧГ=")+"].Номенклатура",

,

Отказ);

КонецЦикла;

КонецПроцедуры

Добавим вызов этой процедуры в ОбработкаПроведения

## Разработка отчета

Отчет строится по РН ТоварыКОформлениюПоступления с отбором ВТ по типу Документа поступления (см. схему)

Чтобы отчет появился в панели отчетов - ОМ ВариантыОтчетовУТПереопределяемый, процедура НастроитьВариантыОтчетов

// {Экзамен

ОписаниеОтчета = ВариантыОтчетов.ОписаниеОтчета(Настройки, Метаданные.Отчеты.экзаменНеоформленныеПоступленияТоваров);

ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "");

ОписаниеВарианта.Описание = НСтр("ru= 'По каким складским документам не оформлены финансовые?'");

ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "Основной");

ОписаниеВарианта.Описание = НСтр("ru= 'По каким складским документам не оформлены финансовые?'");

// }Экзамен

Включить отчет в подсистему Закупки, запустить режим Предприятие с ключом /С ЗапуститьОбновлениеИнформационнойБазы